10 REM NUMBR.ECB
  100 REM ... 6 NUMBER GAMES      RALPH HOPKINS  12-01-78
  120 DIM L(50),T(10),X(4),S$(12),B$(130),G(17),P(17)
  130 PRINT "&K&J"
  140 PRINT TAB(15);"***********************"
  150 PRINT TAB(15);"***  NUMBER  GAMES  ***"
  160 PRINT TAB(15);"***********************"
  170 PRINT
  180 PRINT " 1 ... GUESS       (GUESS THE COMPUTORS NUMBER)"
  190 PRINT " 2 ... NUMBER      (GUESS A NUMBER BETWEEN 1-9999)"
  200 PRINT " 3 ... TAXMAN      (FACTORIAL NUMBER GAME)"
  210 PRINT " 4 ... NUMBER 4    (GUESS A 4 DIGIT NUMBER)"
  220 PRINT " 5 ... NUMBER 5    (GUESS A 5 DIGIT NUMBER)"
  230 PRINT " 6 ... SPOOF       (SPOOF FOR WHO BUYS COFFEE)"
  240 PRINT
  250 PRINT "*** PICK A GAME  (1-6)  ---=>";
  260 INPUT (1,0)X
  270 PRINT
  280 PRINT "&K&JEACH GAME HAS DIRECTIONS FOR PLAY.&J": PAUSE 15
  290 PRINT
  300 LET X=INT(X)
  310 IF X<1 OR X>6 THEN 130 ELSE  PRINT
  320 ON X GOTO 1000,2000,4000,6000,7000,8000
  330 REM
  340 REM
 1000 REM =============== LAST MOD.  8/8/77  R.E.H.
 1010 PRINT TAB(10);"^^^^^^^^^^^^^^^^^^^^^"
 1020 PRINT TAB(10);"^^^   G U E S S   ^^^"
 1030 PRINT TAB(10);"^^^^^^^^^^^^^^^^^^^^^"
 1040 PRINT
 1050 PRINT "    THE OBJECT OF THIS GAME IS"
 1060 PRINT "FOR YOU TO GUESS THE NUMBER"
 1070 PRINT "THIS COMPUTOR HAS CHOOSEN WITHIN"
 1080 PRINT "SO MANY GUESSES."
 1090 PRINT
 1100 PRINT "LET'S BEGIN"
 1110 PRINT
 1120 LET P=P+1
 1130 LET R=10*P
 1140 LET N=INT(RND(0)*R+1)
 1150 PRINT
 1160 PRINT "THE NUMBER IS LESS THAN OR EQUAL TO ";R
 1170 LET T=2
 1180 FOR I=1 TO R
 1190   LET T=T*2
 1200   IF T>R THEN 1220
 1210 NEXT I
 1220 LET T=0
 1230 LET I=I+2
 1240 PRINT "   YOU HAVE ";I;" GUESSES OR I WIN."
 1250 PRINT " NUMBER ";
 1260 INPUT (4,0)" ---=>",G
 1270 IF G<>N THEN 1370
 1280 PRINT "&JYES...  YOU WIN !!.&J"
 1290 LET C=C+1
 1300 PRINT "Would you like to play this game again ?  ";
 1310 INPUT (1,0)"(Yes or No) ---=>",A$
 1320 IF A$="Y" THEN 1120
 1330 PRINT
 1340 PRINT " YOU RETIRE HAVING WON ";C;" GAMES AND LOST "
 1350 PRINT P-C;" GAMES.... GOOD-BYE"
 1360 GOTO 8890
 1370 LET T=T+1
 1380 IF T>=I THEN 1490
 1390 IF G>R THEN 1450
 1400 IF G>N THEN 1430
 1410 PRINT "   ";G;" IS LOW.";
 1420 GOTO 1250
 1430 PRINT "   ";G;" IS HIGH.";
 1440 GOTO 1250
 1450 PRINT "PLEASE PAY ATTENTION."
 1460 PRINT " YOUR GUESS, ";G;" IS GREATER THAN ";R
 1470 PRINT " THE LARGEST YOUR GUESS SHOULD EVER BE."
 1480 GOTO 1250
 1490 PRINT "I WIN.  YOU LOSE."
 1500 PRINT " YOUR STRATEGY CAN BE IMPROVED"
 1510 PRINT " SO THAT I NEVER WIN."
 1520 GOTO 1300
 1530 GOTO 8890
 2000 REM ========== LAST MOD.   8/1/77  R.E.H.
 2010 PRINT TAB(10);"*****  N U M B E R  *****"
 2020 PRINT
 2040 LET A=INT(RND(0)*10000)+1
 2050 PRINT TAB(12);"GAME OF NUMBERS"
 2060 LET B=0
 2070 PRINT " THE OBJECT IS TO GUESS MY NUMBER WHICH IS"
 2080 PRINT " BETWEEN 1 AND 9999.     I WILL TELL YOU IF"
 2090 PRINT " MY NUMBER IS HIGHER OR LOWER THAN YOURS."
 2100 PRINT "INPUTING A ZERO(0) WILL CAUSE ME TO"
 2110 PRINT "  TELL YOU MY NUMBER."
 2120 PRINT TAB(16);"-                            ---------"
 2130 PRINT "&JO.K.&JI have a number...&J"
 2140 LET V=0
 2150 PRINT TAB(40);"YOUR GUESS";
 2160 INPUT (4,0)" ---=>",Y
 2170 IF Y<>0 THEN 2200
 2180 PRINT "MY NUMBER WAS ";A
 2190 GOTO 2310
 2200 PRINT "GUESS NO.";B+1;
 2210 IF Y=A THEN 2290
 2220 IF Y<A THEN 2270
 2230 PRINT "  My number is lower ";
 2240 LET B=B+1
 2250 IF B>20 THEN 2370
 2260 GOTO 2150
 2270 PRINT "  MY NUMBER IS HIGHER ";
 2280 GOTO 2240
 2290 PRINT ,"&J**** CORRECT PICK ****&J"
 2300 LET B=0
 2310 PRINT "WANT TO PLAY AGAIN";
 2320 INPUT (1,200)" ---=>",C$
 2330 IF C$="Y" THEN 2350
 2340 GOTO 2390
 2350 LET A=INT(10000*RND(0))
 2360 GOTO 2130
 2370 PRINT TAB(40);"SORRY ... YOUR OUT OF GUESSES.  THE NO. IS ";A
 2380 GOTO 2300
 2390 GOTO 8890
 2400 REM
 4000 REM CONVERTED FROM MANKATO LIBRARY ON 4/23/75
 4010 REM BY J.STEWART       PROGRAMMER DAVE SKROVE
 4020 REM DATE JANUARY 11,1974
 4030 PRINT TAB(10);"$$$$$$$$$$$$$$$$$$$$$$"
 4040 PRINT TAB(10);"$$$  T A X M A N   $$$"
 4050 PRINT TAB(10);"$$$$$$$$$$$$$$$$$$$$$$"
 4060 PRINT
 4070 PRINT "HI, I AM THE TAXMAN."
 4080 PRINT "Do you want the latest TAX rulings ?  (Y OR N)"
 4090 INPUT (1,200)" ---=>",R$
 4100 IF R$="Y" THEN 5190
 4110 GOSUB 4960
 4120 GOSUB 4190
 4130 GOSUB 4430
 4140 GOSUB 4530
 4150 GOSUB 4620
 4160 IF M=1 THEN 4120
 4170 GOSUB 4810
 4180 GOTO 4900
 4190 PRINT
 4200 PRINT "YOU TAKE";
 4210 INPUT (2,0)" ---=>",K
 4220 LET K=INT(K)
 4230 IF K<=0 THEN 4900
 4240 IF K<=N THEN 4270
 4250 PRINT K;" Is not in the list.&J  TRY AGAIN.&J"
 4260 GOTO 4190
 4270 IF L(K)=0 THEN 4250
 4280 IF K>1 THEN 4320
 4290 PRINT "THERE ARE NO FACTORS OF ";K;" FOR ME."
 4300 PRINT "ARE YOU TRYING TO SHORT-CHANGE THE TAXMAN ???&J"
 4310 GOTO 4190
 4320 LET M=0
 4330 FOR I=1 TO K/2
 4340   IF L(I)=0 THEN 4390
 4350   IF K<>I*INT(K/I) THEN 4390
 4360   LET M=M+1
 4370   LET T(M)=I
 4380   LET L(I)=0
 4390 NEXT I
 4400 IF M=0 THEN 4290
 4410 LET L(K)=0
 4420 RETURN
 4430 LET Y=Y+K
 4440 PRINT "YOUR TOTAL IS ";Y
 4450 PRINT "I GET ";
 4460 FOR I=1 TO M
 4470   PRINT T(I);
 4480   LET Z=Z+T(I)
 4490 NEXT I
 4500 PRINT
 4510 PRINT "MY TOTAL IS ";Z
 4520 RETURN
 4530 PRINT
 4540 PRINT "NEW LIST:";
 4550 LET M=0
 4560 FOR I=1 TO N
 4570   IF L(I)=0 THEN 4600
 4580   PRINT I;
 4590   LET M=1
 4600 NEXT I
 4610 RETURN
 4620 IF M=0 THEN 4800
 4630 FOR I=N TO 4 STEP -1
 4640   FOR J=2 TO I/2
 4650     IF L(J)=0 THEN 4680
 4660     LET M=1
 4670     RETURN
 4680   NEXT J
 4690 NEXT I
 4700 PRINT
 4710 PRINT "I GET ";
 4720 FOR I=1 TO N
 4730   IF L(I)=0 THEN 4760
 4740   PRINT I;
 4750   LET Z=Z+I
 4760 NEXT I
 4770 PRINT " BECAUSE NO FACTORS OF ANY NUMBERS ARE LEFT."
 4780 PRINT "MY TOTAL IS ";Z
 4790 LET M=0
 4800 RETURN
 4810 PRINT
 4820 IF Z>Y THEN 4860
 4830 IF Z=Y THEN 4880
 4840 PRINT " YOU ";Y;"      TAXMAN ";Z;"      YOU WIN!!!"
 4850 RETURN
 4860 PRINT "TAXMAN ";Z;"      YOU ";Y;"      THE TAXMAN WINS."
 4870 RETURN
 4880 PRINT " TAXMAN";Z;"      YOU ";Y;"     TIE GAME!!!!!"
 4890 RETURN
 4900 PRINT
 4910 PRINT
 4920 PRINT "PLAY AGAIN ?   (Y=YES N=NO)";
 4930 INPUT (1,200)" ---=>",R$
 4940 IF R$="N" THEN 5530
 4950 GOTO 4110
 4960 PRINT
 4970 PRINT "HOW MANY NUMBERS DO YOU WANT IN THE LIST";
 4980 INPUT (2,0)" ---=>",N
 4990 LET N=INT(N)
 5000 IF N<=0 THEN 5530
 5010 IF N<51 THEN 5050
 5020 PRINT " AT THIS TIME,REGULATIONS ALLOW"
 5030 PRINT " ........ A MAXIMUM OF 50 NUMBERS."
 5040 GOTO 4960
 5050 LET Y=0
 5060 LET Z=0
 5070 PRINT
 5080 PRINT " THE LIST IS:";
 5090 FOR I=1 TO N
 5100   PRINT I;
 5110   LET L(I)=1
 5120 NEXT I
 5130 IF N>1 THEN 5180
 5140 PRINT
 5150 PRINT "  GENEROUS OF YOU TO FORFEIT ALL TO THE  TAXMAN."
 5160 PRINT " TAXMAN  1    YOU  0      THE TAXMAN WINS."
 5170 GOTO 4900
 5180 RETURN
 5190 PRINT
 5200 PRINT " YOU TRY TO BEAT THE TAXMAN."
 5210 PRINT
 5220 PRINT "   WE START WITH A LIST OF WHOLE NUMBERS IN"
 5230 PRINT " NUMERICAL ORDER (YOU DECIDE HOW MANY)."
 5240 PRINT
 5250 PRINT " YOU TAKE A NUMBER FROM THE LIST -- THE TAXMAN"
 5260 PRINT " GETS ALL THE FACTORS OF YOUR NUMBER THAT"
 5270 PRINT " ARE STILL LEFT.    YOUR NUMBER AND ALL IT'S"
 5280 PRINT " FACTORS ARE THEN DELETED FROM THE LIST."
 5290 GOSUB 5480
 5300 PRINT TAB(10);"FOR EXAMPLE,"
 5310 PRINT " SUPPOSE YOU WANT 10 NUMBERS TO BE IN THE LIST."
 5320 PRINT " THEN THE LIST WOULD BE: 1 2 3 4 5 6 7 8 9 10"
 5330 PRINT
 5340 PRINT " IF YOU TOOK 8, THE TAXMAN WOULD GET 1, 2, AND 4"
 5350 PRINT " AND THE NEW LIST WOULD BE: 3 5 6 7 9 10"
 5360 PRINT
 5370 GOSUB 5480
 5380 PRINT " THE TAXMAN MUST GET *SOMETHING* EVERY TIME SO YOU"
 5390 PRINT " CAN ONLY PICK A NUMBER THAT HAS FACTORS LEFT."
 5400 PRINT
 5410 PRINT "    WHEN NONE OF THE REM AINING NUMBERS HAS"
 5420 PRINT " ANY FACTORS.... THE TAXMAN GETS THEM!!"
 5430 PRINT
 5440 PRINT "YOUR SCORE IS THE SUM OF THE NUMBERS YOU TAKE."
 5450 PRINT "IF YOU WANT TO GIVE UP,TAKE 0."
 5460 PRINT TAB(10);" GOOD LUCK!"
 5470 GOTO 4110
 5480 PRINT
 5490 PRINT " $$$ READY TO SEE MORE $$$ --->";
 5500 INPUT (1,200)I$
 5510 PRINT
 5520 RETURN
 5530 GOTO 8890
 6000 REM ========== LAST MOD.  05-10-78  R.E.H.
 6010 PRINT TAB(10);"********************"
 6020 PRINT TAB(10);"***              ***"
 6030 PRINT TAB(10);"***  N  U  M  4  ***"
 6040 PRINT TAB(10);"***              ***"
 6050 PRINT TAB(10);"********************"
 6060 LET Z=1: PAUSE 10
 6070 LET X(1)=INT(10*RND(0))
 6080 LET X(2)=INT(10*RND(0))
 6090 LET X(3)=INT(10*RND(0))
 6100 LET X(4)=INT(10*RND(0))
 6110 IF X(1)=X(2) OR X(1)=X(3) OR X(1)=X(4) THEN 6070
 6120 IF X(2)=X(3) OR X(2)=X(4) THEN 6070
 6130 IF X(3)=X(4) THEN 6070
 6140 IF C$="Y" THEN 6230 ELSE  PRINT "&K&J"
 6150 PRINT "NEW GAME......&J"
 6160 PRINT "   THIS IS 'DOTS AND PLUSES'.   TRY TO GUESS A 4 DIGIT NUMBER"
 6170 PRINT "THE COMPUTER SELECTS BY ENTERING ANY 4 NUMBERS"
 6180 PRINT "EXAMP....  1,2,3,4...SEPERATE BY COMMAS AND HIT TRANSMIT"
 6190 PRINT "I WILL GIVE YOU A  +   FOR EACH CORRECT NUMBER IN THE RIGHT"
 6200 PRINT "PLACE AND A   .  FOR EACH CORRECT NUMBER IN THE WRONG "
 6210 PRINT "POSITION. ++++ MEANS ALL THE RIGHT NUMBERS ARE IN THE RIGHT PLACES."
 6220 PRINT "**ENTER 0,0,0,0 IF YOU GIVE UP AND WANT TO KNOW THE NUMBER***"
 6230 PRINT "&J","*** NEW GAME ***&J"
 6240 LET Z=1: PRINT " ###  Your 1st guess  ---=>";
 6250 INPUT ,A,B,C,D
 6260 IF A=0 AND B=0 AND C=0 AND D=0 THEN 6520
 6270 LET F=0: LET G=0
 6280 PRINT "   You got    ";
 6290 IF A=X(1) THEN  LET F=F+1
 6300 IF B=X(2) THEN  LET F=F+1
 6310 IF C=X(3) THEN  LET F=F+1
 6320 IF D=X(4) THEN  LET F=F+1
 6330 IF A=X(2) OR A=X(3) OR A=X(4) THEN  LET G=G+1
 6340 IF B=X(1) OR B=X(3) OR B=X(4) THEN  LET G=G+1
 6350 IF C=X(1) OR C=X(2) OR C=X(4) THEN  LET G=G+1
 6360 IF D=X(1) OR D=X(2) OR D=X(3) THEN  LET G=G+1
 6370 IF F=0 THEN  PRINT " ";
 6380 IF F=1 THEN  PRINT "+";
 6390 IF F=2 THEN  PRINT "++";
 6400 IF F=3 THEN  PRINT "+++";
 6410 IF F=4 THEN  PRINT "++++": PRINT "&JYOU GOT IT !&J"
 6420 IF F=4 THEN 6510
 6430 IF G=0 THEN  PRINT " ";
 6440 IF G=1 THEN  PRINT ".";
 6450 IF G=2 THEN  PRINT "..";
 6460 IF G=3 THEN  PRINT "...";
 6470 IF G=4 THEN  PRINT "....";
 6475 IF F=0 AND G=0 THEN  PRINT "* ZIP! *";
 6480 PRINT "  ": PRINT "ENTER YOUR NEXT GUESS ---=>";
 6490 LET Z=Z+1
 6500 GOTO 6250
 6510 PRINT "THAT TOOK ";Z;" GUESSES"
 6520 PRINT "YOUR NUMBER WAS";X(1);;X(2);;X(3);;X(4);
 6530 PRINT "&JWANT TO PLAY AGAIN?  (Y OR N) ";
 6540 INPUT (1,200)" ---=>",C$
 6550 IF C$="Y" THEN 6070 ELSE 8890
 7000 REM ... NUMBER GAME BY  MINI MACK     1977
 7010 PRINT TAB(10);"*********************"
 7020 PRINT TAB(10);"***               ***"
 7030 PRINT TAB(10);"***  N  U  M  5   ***"
 7040 PRINT TAB(10);"***               ***"
 7050 PRINT TAB(10);"*********************"
 7060 PRINT
 7070 PRINT " THIS IS THE NUMBER GAME DO YOU KNOW HOW TO PLAY ?&J"
 7080 INPUT (1,200)"*** (Y or N) ---=>",F$
 7090 IF F$="Y" THEN 7230 ELSE  PRINT "&K&J"
 7100 PRINT " INSTRUCTIONS"
 7110 PRINT
 7120 PRINT " A ZERO WILL SHOW YOU MY GUESS AND STOP THE PROGRAM"
 7130 PRINT " NO TWO DIGITS IN MY 5 DIGIT NUMBER ARE THE SAME."
 7140 PRINT " MY FIVE DIGIT NUMBER is inputted without separating commas."
 7150 PRINT " EXAMPLE: '12345' .  YOU ARE TRYING TO GUESS MY NUMBER"
 7160 PRINT " A '.' MEANS ONE OF YOUR NUMBERS IS ONE OF MINE"
 7170 PRINT " BUT NOT IN THE EXACT POSITION OF MINE.&J"
 7180 PRINT " TO CONTINUE type something and then hit RETURN ---=>";
 7190 INPUT (1,200)F$
 7200 PRINT "&J A '+' MEANS ONE OF YOUR NUMBERS IS ONE OF MINE IN"
 7210 PRINT " THE EXACT POSITION OF MINE"
 7220 PRINT " A 'MISS ' IS WHEN NONE OF YOUR DIGITS ARE EQUAL TO ANY OF MINE"
 7230 LET S$="            "
 7240 LET A=1
 7250 GOSUB 7510
 7260 GOSUB 7610
 7270 GOSUB 7850
 7280 GOSUB 7920
 7290 IF P=5 THEN 7470
 7300 IF D=0 AND P=0 THEN 7310 ELSE 7370
 7310 LET S$="  M I S S   "
 7360 GOTO 7460
 7370 IF D=0 THEN 7420
 7380 FOR C=1 TO D
 7390   LET S$(C*2,(C*2)+1)=" ."
 7400 NEXT C
 7420 FOR C=D+1 TO P+D: LET S$(C*2,(C*2)+1)=" +": NEXT C
 7430 FOR C=P+D+1 TO 5
 7440   LET S$(C*2,(C*2)+1)="  "
 7450 NEXT C
 7460 GOTO 7260
 7470 PRINT : PRINT " YOU WON IN ";A-1;" GUESSES&J"
 7480 PRINT " CARE TO TRY AGAIN";
 7490 INPUT (1,200)" ---=>",F$
 7500 IF F$="Y" THEN 7070 ELSE 8890
 7510 LET X1=INT(10*RND(0))
 7520 LET X2=INT(10*RND(0))
 7530 IF X2=X1 THEN 7520
 7540 LET X3=INT(10*RND(0))
 7550 IF X3=X1 OR X3=X2 THEN 7540
 7560 LET X4=INT(10*RND(0))
 7570 IF X4=X1 OR X4=X2 OR X4=X3 THEN 7560
 7580 LET X5=INT(10*RND(0))
 7590 IF X5=X1 OR X5=X2 OR X5=X3 OR X5=X4 THEN 7580
 7600 RETURN
 7610 PRINT S$: PRINT " GUESS NO.";A;" YOUR GUESS ";
 7620 INPUT ,(5,0)" ---=>",G
 7630 IF G<>0 THEN 7660 ELSE  PRINT
 7640 PRINT "MY NUMBER WAS ";X1;X2;X3;X4;X5;"&JBYE&J&J"
 7650 GOTO 8890
 7660 LET G1=INT(G/10000)
 7670 LET G2=INT((G-G1*10000)/1000)
 7680 LET G3=INT((G-G1*10000-G2*1000)/100)
 7690 LET G4=INT((G-G1*10000-G2*1000-G3*100)/10)
 7700 LET G5=INT((G-G1*10000-G2*1000-G3*100)-G4*10)
 7710 IF G1=G2 OR G1=G3 OR G1=G4 OR G1=G5 THEN 7770
 7720 IF G2=G3 OR G2=G4 OR G2=G5 THEN 7770
 7730 IF G3=G4 OR G3=G5 THEN 7770
 7740 IF G4=G5 THEN 7770
 7750 LET A=A+1
 7760 RETURN
 7770 PRINT " NO TWO DIGITS ARE ALIKE!"
 7780 LET A=A+1: PRINT "YOU FORFIET YOUR GUESS.",
 7790 LET S$="  M I S S   "
 7840 GOTO 7610
 7850 LET P=0
 7860 IF G1=X1 THEN  LET P=P+1
 7870 IF G2=X2 THEN  LET P=P+1
 7880 IF G3=X3 THEN  LET P=P+1
 7890 IF G4=X4 THEN  LET P=P+1
 7900 IF G5=X5 THEN  LET P=P+1
 7910 RETURN
 7920 LET D=0
 7930 IF G1=X2 OR G1=X3 OR G1=X4 OR G1=X5 THEN  LET D=D+1
 7940 IF G2=X1 OR G2=X3 OR G2=X4 OR G2=X5 THEN  LET D=D+1
 7950 IF G3=X1 OR G3=X2 OR G3=X4 OR G3=X5 THEN  LET D=D+1
 7960 IF G4=X1 OR G4=X2 OR G4=X3 OR G4=X5 THEN  LET D=D+1
 7970 IF G5=X1 OR G5=X2 OR G5=X3 OR G5=X4 THEN  LET D=D+1
 7980 RETURN
 7990 GOTO 8890
 8000 REM ....."SPOOF" for who-buys-coffee  Jeff Rickert 1977
 8010 PRINT "&K&J           COMPUTOR GAME OF"
 8020 PRINT
 8030 PRINT "      *****  S P O O F  *****&J"
 8040 LET B$=" ": LET X=0
 8050 FOR X=1 TO 16: LET B$=B$+"        ": NEXT X
 8060 PRINT "SPOOF to see who buys coffee.   Each player"
 8062 PRINT "must guess how many coins EVERYBODY combined"
 8064 PRINT "is holding.  Each player can hold 0, 1, 2, or 3"
 8065 PRINT "coins secretly.  After each person guesses, all"
 8067 PRINT "hidden hands are shown.  Whoever guessed the"
 8068 PRINT "correct total is ELIMINATED and DOES NOT buy"
 8069 PRINT "coffee or continue with the guessing.&J"
 8070 GOSUB 8150
 8080 GOSUB 8210
 8090 GOSUB 8330
 8100 GOSUB 8420
 8110 GOSUB 8840
 8120 GOSUB 8640
 8130 GOTO 8090
 8140 GOTO 8890
 8150 REM ======= *NUMBER OF PLAYERS*
 8160 PRINT "&JHow many want to play? (2 to 16) ---=>";
 8170 INPUT (2,0)N
 8180 IF N<=0 OR N<>INT(N) THEN 8150
 8185 IF N>16 THEN  PRINT "&J16 PLAYERS ARE ENOUGH!&J": GOTO 8150
 8190 FOR E=1 TO N: LET M=RND(0): NEXT E
 8200 LET M=N: RETURN
 8210 REM ======= *PLAYERS NAMES*
 8220 FOR E=1 TO N
 8230   GOTO 8250
 8240   PRINT "WE ALREADY HAVE THAT PLAYER"
 8250   PRINT "INPUT player ";E;"'s name (8 letters max.)";
 8260   INPUT (8,0)" ---=>",B$((E*8)-7,E*8)
 8270   IF E=1 THEN 8310
 8280   FOR F=1 TO E-1
 8290     IF B$((F*8)-7,F*8)=B$((E*8)-7,E*8) THEN 8240
 8300   NEXT F
 8310 NEXT E
 8320 RETURN
 8330 REM ======= *RANDOM NUMBERS*
 8340 FOR E=1 TO N
 8350   LET P(E)=INT(4*RND(0))
 8360 NEXT E
 8370 LET T=0
 8380 FOR E=1 TO N
 8390   LET T=T+P(E)
 8400 NEXT E
 8410 RETURN
 8420 REM =======  *INPUT X*
 8430 FOR E=N TO 1 STEP -1
 8440   LET B$(((E+1)*8)-7,(E+1)*8)=B$((E*8)-7,E*8)
 8450 NEXT E
 8460 LET B$(1,8)=B$(((N+1)*8)-7,(N+1)*8)
 8470 FOR E=1 TO N
 8480   GOTO 8500
 8490   PRINT "&J*** NO TWO GUESSES ARE ALIKE ***&J"
 8500   SET DS=0: PRINT B$((E*8)-7,E*8);
 8505   PRINT ",your GUESS possiblity of ";N*3;
 8510   INPUT (2,0)" ---=>",G(E)
 8520   LET R=0
 8530   IF E=1 THEN 8620
 8540   FOR F=1 TO E-1
 8550     IF G(E)<>G(F) THEN 8570
 8560     LET R=R+1
 8570     IF R>=1 AND N<=3 THEN 8490
 8580   NEXT F
 8590   IF R<2 THEN 8610
 8600   PRINT "ALREADY HAVE THAT GUESS TWICE"
 8610   IF R>=2 THEN 8500
 8620 NEXT E
 8630 RETURN
 8640 REM ======= *COMPARE*
 8650 FOR E=1 TO N
 8660   IF G(E)=T THEN 8690
 8670 NEXT E
 8680 RETURN
 8690 LET N=N-1
 8700 IF N=1 THEN 8760
 8710 PRINT B$((E*8)-7,E*8);" YOUR LUCKY YOUR OUT"
 8720 FOR F=E TO N+1
 8730   LET B$((F*8)-7,F*8)=B$(((F+1)*8)-7,(F+1)*8)
 8740 NEXT F
 8750 GOTO 8680
 8760 PRINT B$((E*8)-7,E*8);" YOUR LUCKY YOUR OUT"
 8770 IF E=1 THEN 8810
 8780 PRINT B$(1,8);"  YOU LOSE ......"
 8790 PRINT " THAT WILL BE ";INT(M*15*1.04);" CENTS"
 8800 GOTO 8890
 8810 PRINT B$(9,16);" YOU LOSE ...."
 8820 PRINT " THAT WILL BE";INT(M*15*1.04);" CENTS"
 8830 GOTO 8890
 8840 FOR E=1 TO N
 8850   PRINT B$((E*8)-7,E*8);" had ";P(E);" coin(s)"
 8860 NEXT E
 8870 PRINT TAB(X);"TOTAL ";T
 8880 RETURN
 8890 PRINT
 8900 PRINT " DO YOU WANT TO TRY A DIFFERENT GAME?"
 8910 PRINT "   (Y OR N)   ---=>";
 8920 INPUT (1,200)F$
 8930 IF F$="Y" THEN 130
 8940 END