100 REM ... JOTTO.ECB ..by Andrea Barsh and Duff Kurland  4/2/73
  110 REM ................at NYU's UHMC Computor Center
  120 REM ...Last revison:  03-07-81  R.E.H.
  130 DIM W(5),T(60),D$(5),W$(5),T$(5),Z$(1000)
  135 REM ...Varibles used:  A, B, C, I, J, W, Z, D$, T$, W$, Z$
  140 LET W=0: PRINT "&K&J&J"
  170 DATA "MIDST","INDEX","THIGH","XENON","PROXY","DOUBT","THUMB","DIGIT"
  180 DATA "LIVID","FUGUE","ERROR","BACON","FUDGE","JUDGE","GUIDE","PRIVY"
  190 DATA "LOWLY","EXULT","GNOME","TEMPO","WRYLY","LYMPH","TEMPT","INGOT"
  200 DATA "FILET","JUMPY","UNITE","IGLOO","CREEP","ANNOY","TROLL","MONTH"
  210 DATA "EVERY","ENEMY","VEXED","GLOOM","VAGUE","DWARF","VALET","INEPT"
  220 DATA "ARGUE","RADAR","MERCY","COMBS","CLIMB","COVER","CANOE","OCEAN"
  230 DATA "PHYLA","WIPED","BLIMP","FEUDS","CHEWY","COUPS","CAMEO","HYMNS"
  240 DATA "PSALM","CHECK","SPAWN","TAWNY","FAWNS","AXIOM","OUSTS","ATONE"
  250 DATA "BELCH","THUGS","GULPS","GUSTO","AROMA","YOUTH","YELPS","WHOOP"
  260 DATA "LAUGH","COUGH","GNAWS","NOISE","BOOZE","GULCH","ONION","HONOR"
  270 DATA "THREE","FIFTY","SIXTY","IONIC","CONIC","KNAVE","NEWLY","THIRD"
  280 DATA "FIFTH","SASSY","RAZOR","KAZOO","SEXES","BIBLE","AWFUL","MAGIC"
  290 DATA "LISPS","CLASP","GRAPE","SLYLY","LUCID","QUEUE","RUMOR","PIXIE"
  300 DATA "PRISM","CRIBS","WILTS","BATHE","BUTTE","BLEAT","COMMA","MOCHA"
  310 DATA "KYACK","NAIVE","PROWL","KNEEL","AGLOW","AUDIO","SIEGE","SATYR"
  320 DATA "DEITY","DIETS","FRETS","YIELD","PROPS","GAUGE","WRING","GLAZE"
  330 DATA "FRIAR","RIVER","UMBRA","SCOLD","SEWER","KNOWN","KNISH","CADET"
  340 DATA "LAPEL","ITCHY","LIMBO","TALON","SURLY","PITHY","ANVIL","GURUS"
  350 DATA "HERON","SHELF","WASPS","WAFER","AVOID","HUMOR","WRECK","HAVOC"
  360 DATA "SKULK","GUILD","TOWEL","TWEAK","ABOVE","AZURE","BLURT","PANIC"
  370 DATA "CRUEL","TWIRL","ROTOR","CHIEF","WEIRD","ROBOT","CANAL","SCAMP"
  380 DATA "SCOWL","WIVES","SIEVE","ALIBI","OASIS","ISSUE","AORTA","PIZZA"
  390 DATA "SURGE","OCCUR","IRONY","WORDY","EDIFY","SHEDS","INPUT","LEAST"
  400 DATA "PUPPY","MESSY","MUMPS","FUNNY","PRINT","TULIP","TOXIC","CURIO"
  410 DATA "FIXED","VOMIT","STEAK","WINCH","RADIO","TORCH","ERUPT","GAUZE"
  420 PRINT TAB(15);"*******************"
  430 PRINT TAB(15);"***  J O T T O  ***"
  440 PRINT TAB(15);"***  WORD GAME  ***"
  450 PRINT TAB(15);"*******************&J&J": LET T=0
  460 PRINT "     (Please WAIT a minute while I get ready)&J&J"
  465 FOR X=1 TO 200
  470   READ D$: LET Z$=Z$+D$
  475 NEXT X
  480 PRINT "Do you need DIRECTIONS (Y or N) ---=>";
  490 INPUT (1,0)T$: LET T$=T$+"Y": PRINT
  500 IF T$(1,1)="N" THEN 650
  510 IF T$(1,1)="n" THEN 650 ELSE  PRINT "&K"
  530 PRINT "I THINK OF A 5-LETTER WORD, AND YOU GUESS IT BY"
  540 PRINT "GIVING ME TEST WORDS (ALSO 5 LETTERS).  I'LL"
  550 PRINT "TELL YOU HOW MANY LETTERS IN YOUR TEST WORD"
  560 PRINT "ALSO APPEAR IN MY SECRET WORD. "
  570 PRINT "       THESES ARE CALLED 'JOTS'...."
  580 PRINT "DOUBLE LETTERS COUNT SEPARATELY,"
  590 PRINT "     EACH LETTER ON ITS OWN."
  600 PRINT "If you want to concede, type 'STOP' or 'QUIT'"
  650 PRINT
  660 PRINT "YOU ARE ON YOUR HONOR TO USE REAL ENGLISH WORDS"
  670 PRINT " FOR TEST WORDS."
  680 PRINT " ELIMINATING ALPHABET:"
  690 PRINT
  700 PRINT "A B C D E F G H I J K L M N O P Q R S T U V ";
  710 PRINT "W X Y Z"
  720 PRINT
  730 LET Z=INT(RND(0)*200)+1
  740 LET W$=Z$(Z*5-4,Z*5)
  750 FOR I=1 TO 5: LET W(I)=ASC(W$(I,I)): NEXT I
  760 LET C=0
  770 PRINT "ENTER a test word ---=>";
  780 INPUT (5,0)T$: LET T$=T$+"     "
  790 IF T$=W$ THEN 990
  800 FOR I=1 TO 5: LET T(I)=ASC(T$(I,I)): NEXT I
  810 IF T(1)=32 THEN 880: REM ...a space !
  820 IF T$(1,4)="GIVE" THEN 1060
  821 IF T$(1,4)="STOP" THEN 1060
  822 IF T$(1,4)="QUIT" THEN 1060
  823 IF T$(1,4)="EXIT" THEN 1060
  825 GOTO 850
  830 PRINT "TEST WORD MUST BE 5 LETTERS"
  840 GOTO 770
  850 FOR I=1 TO 5
  855   IF T(I)<65 OR T(I)>122 THEN  EXIT 830
  860   IF T(I)>90 AND T(I)<97 THEN  EXIT 830
  865   IF T(I)>90 THEN  LET T(I)=T(I)-32: REM ...Make lower case
  870 NEXT
  880 LET C=C+1
  890 LET J=0
  900 FOR A=1 TO 5
  910   FOR B=1 TO 5
  920     IF W(A)<>T(B) THEN 950
  930     LET J=J+1
  940     LET T(B)=5
  950   NEXT B
  960 NEXT A
  970 IF J=1 THEN  PRINT J;" Jot" ELSE  PRINT J;" Jots"
  980 IF J<5 THEN 770
  990 LET C=C+1
 1000 PRINT "YOU GOT IT in ";C;" tries!"
 1010 PRINT "Do you want to play again ---=>";
 1020 INPUT (1,0)T$: LET T$=T$+"Y": PRINT
 1030 IF T$(1,1)="Y" THEN 670
 1040 IF T$(1,1)="y" THEN 670
 1050 GOTO 1080
 1060 PRINT "My word was ";W$
 1070 GOTO 1010
 1080 PRINT TAB(9);"&JThanks for playing JOTTO."
 1090 END