100 REM ...DECAY.ECB ..from ?? via Roseville REVISED NOV. 26,1968
  110 REM ...by RICHARD F. PAV, PATCHOGUE H.S., (PHYSICS)
  120 REM ...THIS IS A GAME BASED ON RADIOACTIVE DECAY.
  125 PRINT "&K&J&J": REM ...Minor revision 3-15-81  R.E.H.
  130 PRINT "              ---THE NEW CLEA CASINO---"
  140 PRINT
  150 PRINT "    MR. A. TOM MICK, GENERAL MANAGER OF THE NEW CLEA CASINO"
  160 PRINT "HAS, AT TIME  T=0,  DISCOVERED  100,000 RADIOACTIVE PLAYING"
  170 PRINT "CHIPS AT HIS TABLE. THEIR HALF-LIFE IS 10 MINUTES. EACH CHIP"
  180 PRINT "TRANSMUTES SPONTANEOUSLY AND COMPLETELY IN A RANDOM FASHION."
  190 PRINT
  200 PRINT "    AT VARIOUS TIMES T, AFTER T=0, YOU MUST DETERMINE WITHIN"
  210 PRINT "A CERTAIN PERCENTAGE, HOW MANY CHIPS ARE LEFT."
  212 PRINT
  215 INPUT (1,0)" <*> Enter any letter to see more ---=>",I$
  220 PRINT "&K"
  230 PRINT "    TO FURTHER THE INTEREST OF THE GAME, YOU WILL START WITH"
  240 PRINT "$1,000 AND THE HOUSE WITH AN UNSPECIFIED AMOUNT.  HALF THE"
  250 PRINT "MONEY YOU HAVE WILL RIDE ON EACH GUESS YOU TAKE.  LET'S SEE"
  260 PRINT "IF YOU CAN BREAK THE HOUSE BEFORE THE CHIPS RUN OUT."
  270 PRINT
  280 PRINT "THE HOUSE OFFERS THE FOLLOWING ODDS:"
  290 PRINT "     2) 2 TO 1 ODDS FOR GUESSING WITHIN 20 PERCENT"
  300 PRINT "     4) 4 TO 1 ODDS FOR GUESSING WITHIN 10 PERCENT"
  310 PRINT "     8) 8 TO 1 ODDS FOR GUESSING WITHIN  5 PERCENT."
  320 PRINT
  330 PRINT "ENTER THE NUMBER 2, 4, OR 8 FOR THE ODDS YOU WANT AFTER THE"
  340 PRINT "QUESTION MARK IN THE COLUMN LABELLED ODDS."
  350 PRINT
  360 PRINT "YOUR $","HOUSE $","TIME (MIN)","ODDS"
  370 LET A=0
  380 LET B=0
  390 LET T=0
  400 LET Y=1000
  410 LET C=0
  420 PRINT
  430 IF ABS(G-D)<1500 THEN 460
  440 LET G=5
  450 LET D=2
  460 LET B=B+1
  470 FOR I=1 TO 3+A+ABS(G-D)
  480   LET T3=INT(100*RND(0))/10
  490 NEXT I
  500 LET T=T+T3
  510 LET D=INT(1E5*EXP(-.0693*T))
  520 IF D=0 THEN 870
  530 PRINT Y,1001000-Y,T,
  540 INPUT A
  550 IF A=2 THEN 620
  560 IF A=4 THEN 620
  570 IF A=8 THEN 620
  580 PRINT "SORRY PAL, WE DONT OFFER THOSE ODDS."
  590 IF C=1 THEN 830
  600 LET C=1
  610 GOTO 530
  620 PRINT "HOW MANY CHIPS LEFT ";
  630 INPUT G
  640 PRINT "ACTUAL NUMBER LEFT IS ";D
  650 IF A=2 THEN 710
  660 IF A=4 THEN 690
  670 LET P=.05
  680 GOTO 720
  690 LET P=.1
  700 GOTO 720
  710 LET P=.2
  720 LET T=10*B
  730 IF ABS(D-G)<=P*D THEN 780
  740 LET Y=INT(Y-Y/2)
  750 IF Y<=50 THEN 830
  760 PRINT "TOO BAD, YOU LOST. TRY AGAIN."
  770 GOTO 410
  780 LET Y=INT(Y+A*Y/2)
  790 IF 1000000-Y<1 THEN 900
  800 IF Y>2E5 THEN 850
  810 PRINT "YOU WON. TRY AGAIN."
  820 GOTO 410
  830 PRINT "IT SEEMS YOU JUST CANT GET THE HANG OF IT. SAVE YOUR BREAD."
  840 GOTO 980
  850 PRINT "YOU CAN BREAK THE HOUSE IF YOU TRY A LONG SHOT."
  860 GOTO 410
  870 PRINT "OOOOPS... SORRY PAL, THE LAST CHIP JUST DISINTEGRATED."
  880 PRINT "THE HOUSE IS CLOSED."
  890 GOTO 980
  900 PRINT "YOU BROKE THE HOUSE. YOU NEEDED ONLY ";
  910 LET Y=1001000
  920 IF B>5 THEN 950
  930 PRINT "THE MINIMUM NUMBER OF GUESSES."
  940 GOTO 960
  950 PRINT B;"GUESSES."
  960 PRINT "CONGRATULATIONS."
  970 PRINT "YOU MUST KNOW A LOT ABOUT RADIOACTIVITY AND THINGS."
  980 PRINT "THANKS FOR PLAYING.."
  990 PRINT
  995 INPUT (1,0)" <*> Enter any letter to get CHECK ---=>",I$
  996 PRINT "&K"
 1000 PRINT "-------------------------------------------------------------"
 1020 PRINT "                                        CHECK NO.";B+D
 1040 PRINT "                                     DATE: ";
 1050 PRINT "-------------19--"
 1060 PRINT
 1080 PRINT " PAY TO THE ORDER OF--";
 1090 PRINT "------CASH------";
 1100 PRINT "$";Y
 1110 PRINT
 1120 PRINT
 1130 PRINT " THE NEW CLEA CASINO                    A. TOM MICK"
 1140 PRINT "                                        GENERAL MANAGER"
 1150 PRINT
 1160 PRINT "------------------------------------------------------------"
 1170 PRINT
 1180 PRINT "DONT SPEND IT ALL IN ONE PLACE."
 1190 END