1 REM CELL.ECB
    2 REM ========== BY KEN WITT     TRACY HIGH SCHOOL
    3 READ H,S,K,N,C,W,P
    4 DATA 6700,30,53,0,1,0,0
    5 PRINT "DO YOU WISH TO SEE AN EXPLANATION OF THIS PROGRAM"
    6 PRINT "(Y=yes, N=no) ---=>";
    7 INPUT (1,0)Q$: LET Q$=Q$+"N"
    8 IF Q$(1,1)="N" THEN 1650
    9 LET A9$="----------------------------------------------"
   10 PRINT "IN THIS PROGRAM YOU WILL BE ROLE PLAYING. YOU WILL ACT AS"
   11 PRINT "A CELL MEMBRANE AND YOUR RESPONSIBILITY WILL BE TO MAKE"
   12 PRINT "ADJUSTMENTS IN THE FOLLOWING ITEMS:"
   13 PRINT "1.WATER"
   14 PRINT "2.SUGAR"
   15 PRINT "3.POTASSIUM IONS"
   16 PRINT "4.SODIUM IONS"
   17 PRINT "5.CHLORIDE IONS"
   18 PRINT "6.WASTE(PRIMARILY AMMONIA COMPOUNDS)"
   19 PRINT A9$
   20 PRINT "SAFE CONCENTRATIONS ARE AS FOLLOWS:"
   21 PRINT "          WATER BETWEEN 6000 AND 8000 MOLECULES"
   22 PRINT "          SUGAR BETWEEN 10 AND 35 MOLECULES"
   23 PRINT "          POTASSIUM BETWEEN 40 AND 53 IONS"
   24 PRINT "          SODIUM BETWEEN 0 AND 13 IONS"
   25 PRINT "          CHLORIDE BETWEEN 1 AND 3 IONS"
   26 PRINT "          WASTE BETWEEN 0 AND 10 MOLECULES"
   27 PRINT A9$
   30 PRINT
   31 PRINT
   32 PRINT "YOU WILL BE A CELL MEMBRANE OF ESCHERICHIA COLI. YOUR"
   33 PRINT "CONCENTRATIONS ARE:"
   34 PRINT "          WATER-67% OR 6700 MOLECULES     SUGAR-30 MOLECULES"
   35 PRINT "          POTASSIUM IONS-53            NO SODIUM OR WASTE"
   36 PRINT "          A TRACE OF CHLORIDE ION"
   37 GOTO 1650
   38 PRINT
   39 PRINT A9$
   40 PRINT "UNDERSTAND THAT AS YOU DO ANY OF THE FOLLOWING ENERGY WILL"
   41 PRINT "BE USED UP IN THE AMOUNTS SHOWN."
   42 PRINT "      GET RID OF WASTE-4 MOLECULES OF SUGAR"
   44 PRINT A9$
   45 PRINT "CHANGES IN THE CELL DUE TO OSMOSIS AND DIFFUSION TAKE"
   46 PRINT "PLACE AUTOMATICALLY. OTHER ENERGY FOR OTHER FUNCTIONS"
   47 PRINT "OF THE CELL, SUCH AS PREPARATION FOR REPRODUCTION ALSO"
   48 PRINT "DEPRICIATE AUTOMATICALLY."
   50 PRINT "WASTE BUILD UP FROM SUCH ENERGY ALSO TAKES PLACE."
   51 PRINT
   52 PRINT "PRETEND YOU ARE NOW PLACED INTO A SOLUTION WHICH HAS THE"
   53 PRINT "FOLLOWING CONCENTRATIONS:"
   54 PRINT "(THE CONCENTRATIONS OF THIS SOLUTION ALWAYS REMAINS CONSTANT)"
   55 PRINT "      WATER-87%            SUGAR-10%         SODIUM-TRACE"
   56 PRINT "      POTASSIUM-TRACE      CHLORIDE-TRACE"
   57 PRINT "*********************************************************"
   58 PRINT "THE CELL NOW BEGINS TO BURN SUGAR FOR ENERGY. DIFUSION AND"
   59 PRINT "OSMOTIC POTENTIALS GO INTO EFFECT. YOU ARE NOW READY TO"
   60 PRINT "ATTEMPT TO KEEP THIS CELL ALIVE!"
   65 PRINT "========================================================="
   68 LET J=0
   69 LET P=P+1
   70 IF P=13 THEN 1622
   71 PRINT "CHOOSE THE NUMBER OF THE ITEM YOU WISH TO CHANGE!"
   72 INPUT X
   80 LET H=H+400
   90 LET S=S-4
  100 LET K=K-2
  110 LET N=N+2
  120 LET W=W+4
  130 IF X=1 THEN 200
  140 IF X=2 THEN 350
  150 IF X=3 THEN 450
  160 IF X=4 THEN 480
  170 IF X=5 THEN 550
  180 IF X=6 THEN 600
  200 PRINT "WHAT IS THE NUMBER OF WATER MOLECULES YOU WANT REMOVED"
  220 INPUT A
  221 IF A<H THEN 230
  222 PRINT "YOU DONT HAVE THAT MANY DUM-DUM!!!"
  223 GOTO 200
  230 LET H=H-A
  232 PRINT "ENERGY IS USED HERE TO GET RID OF WATER."
  235 LET S=S-4
  240 PRINT
  241 PRINT "PRESENT CONCENTRATIONS ARE AS FOLLOWS:"
  250 PRINT "POTASSIUM IONS--";K,"WASTE MOLECULES--";W
  260 PRINT "SODIUM INS--";N,"WATER MOLECULES--";H
  270 PRINT "CHLORIDE IONS--";C,"SUGAR MOLECULES--";S
  280 PRINT
  310 IF H<6000 THEN 1000
  311 IF H>8000 THEN 1000
  312 IF S<10 THEN 1100
  313 IF S>35 THEN 1100
  314 IF K<40 THEN 1200
  315 IF K>60 THEN 1200
  320 IF W>10 THEN 1500
  321 GOTO 68
  350 PRINT "HOW MANY SUGAR MOLECULES DO YOU WANT"
  360 INPUT B
  370 IF B<150 THEN 390
  380 PRINT "THE SOLUTION CANNOT OFFER YOU THAT MANY AT ONCE!"
  385 GOTO 350
  390 LET S=S+B
  400 PRINT "ENERGY IS NEEDED FOR PINOCYTOSIS!"
  410 LET S=S-3
  420 GOTO 240
  450 PRINT "POTASSIUM IONS ARE REGULATED BY ACTIVE TRANSPORT."
  451 PRINT "MORE SPECIFIC POTASSIUM IONS ARE REGULATED BY THE"
  452 PRINT "SODIUM PUMP, WHICH IS FOR EVERY SODIUM ION PUMPED OUT"
  453 PRINT "ONE POTASSIUM ION IS GAINED ON THE INSIDE OF THE MEMBRANE"
  460 GOTO 69
  480 PRINT "HOW MANY SODIUM IONS DO YOU WANT REMOVED"
  490 INPUT D
  500 IF D<N THEN 510
  505 PRINT "YOU DO NOT HAVE THAT MANY!!!"
  506 GOTO 480
  510 LET N=N-D
  515 LET K=K+D
  520 PRINT "ENERGY IS NEEDED FOR ACTIVE TRANSPORT!!"
  530 LET S=S-2
  540 GOTO 240
  550 PRINT "YOU HAVE LITTLE OR NO CONTROL OR NEED TO CORRECT THE"
  551 PRINT "CHLORIDE ION CONCENTRATION!!"
  560 GOTO 69
  600 PRINT "HOW MANY WASTE MOLECULES DO YOU WANT TO GET RID OF"
  610 INPUT E
  620 IF E<W-3 THEN 640
  630 PRINT "YOU DO NOT HAVE THAT MANY TO GET RID OF!"
  635 GOTO 600
  640 LET W=W-E
  650 PRINT "ENERGY IS NEEDED TO GET RID OF WASTE!"
  660 LET S=S-4
  670 GOTO 240
 1000 PRINT "***CRISIS***  ADJUST WATER CONCENTRATION IMMEDIATELY!!"
 1010 LET J=J+1
 1020 GOTO 1600
 1100 PRINT "***CRISIS***  ADJUST SUGAR CONCENTRATION IMMEDIATELY!!"
 1101 IF S>0 THEN 1110
 1102 PRINT "YOU ARE BURNING PROTOPLASM DUMB-DUMB."
 1110 LET J=J+1
 1120 GOTO 1600
 1200 PRINT "***CRISIS***  ADJUST POTASSIUM ION CONCENTRATION "
 1201 PRINT "              IMMEDIATELY!!"
 1210 LET J=J+1
 1220 GOTO 1600
 1500 PRINT "***CRISIS***  ADJUST WASTE CONCENTRATION IMMEDIATELY!!"
 1510 LET J=J+1
 1520 PRINT
 1600 IF J<3 THEN 6
 1610 PRINT "YOU DID NOT FUNCTION WELL AS A CELL MEMBRANE."
 1620 PRINT "***YOUR CELL IS NOW DEAD********"
 1621 GOTO 1630
 1622 PRINT "***VERY GOOD***  YOU HAVE MAINTAINED THE CELL LONG"
 1623 PRINT "ENOUGH TO REACH MATURITY. THE CELL IS NOW ABOUT TO"
 1624 PRINT "REPRODUCE. DO YOU WISH TO TRY TO KEEP ONE OF THE "
 1625 PRINT "DAUGHTER CELLS ALIVE (1=YES AND 0=NO)"
 1626 INPUT Q
 1627 LET P=0
 1628 IF Q=1 THEN 68
 1630 STOP
 1650 PRINT "DO YOU WISH TO SEE AN EXPLANATION OF CONCENTRATIONS"
 1660 PRINT "AND RULES  (Y=yes, and N=no) ---=>";
 1670 INPUT (1,0)Z$
 1675 IF LEN(Z$)=0 THEN  LET Z$="N"
 1680 IF Z$(1,1)="Y" THEN 38
 1690 IF Z$(1,1)="N" THEN 68
 1750 END