10 REM CALEN.ECB
   15 REM ..CALENDAR.....UTS-700        4-11-80    R.E.H.
   20 REM ..BOOK: 101 BASIC COMPUTOR GAMES    page 65
   30 REM ..Values for 1980:  See NOTES
   40 DIM M(59),N(100),X$(60)
   50 LET J$="&J": PRINT "&K";J$;J$
   60 FOR I=1 TO 59: LET X$=X$+"*": NEXT I
   70 REM ..1980 Starts on Tue. (0=SUN, -1=MON, -2=TUE, ...)
   80 REM ..D = 1st day    1980: TUE.
   90 LET S=0
  100 PRINT TAB(15);"CALENDAR";J$
  110 PRINT TAB(15);"(0) - 1980"
  120 PRINT TAB(15);"(1) - 1981"
  130 PRINT TAB(15);"(2) - 1982"
  140 PRINT TAB(15);"(3) - 1983"
  150 PRINT TAB(15);"(4) - 1984"
  160 PRINT TAB(15);"(5) - 1985"
  170 PRINT TAB(15);"(6) - 1986"
  180 PRINT TAB(15);"(7) - 1987"
  190 PRINT TAB(15);"(8) - 1988"
  200 PRINT TAB(15);"(9) - 1989"
  210 INPUT (1,0)"*#* Pick one ---=>",N: LET N=N+1
  220 PRINT : IF N<1 OR N>10 THEN 50
  230 REM ..Read 1st day of chosen year and year
  240 FOR I=1 TO N: READ D: READ Z: NEXT I
  250 DATA -2,1980,-4,1981,-5,1982,-6,1983,-7,1984
  260 DATA -1,1985,-2,1986,-3,1987,-4,1988,-6,1989
  270 RESTORE 300
  280 REM ..Read days of each month
  290 FOR N=1 TO 12: READ M(N): NEXT N
  300 DATA 31,28,31,30,31,30,31,31,30,31,30,31
  310 IF Z/4=INT(Z/4) THEN  LET Z1=1 ELSE  LET Z1=0
  320 IF Z1=1 THEN  LET M(2)=29: REM ...Leap year
  330 FOR N=1 TO 12
  340   LET D3=0: LET D4=0
  350   PRINT J$;J$;J$: IF N>1 THEN  LET S=S+M(N-1)
  360   PRINT "**";S;TAB(7);"******************";
  370   ON N GOTO 380,390,400,410,420,430,440,450,460,470,480,490
  380   PRINT " JANUARY ";: GOTO 500
  390   PRINT " FEBRUARY";: GOTO 500
  400   PRINT "  MARCH  ";: GOTO 500
  410   PRINT "  APRIL  ";: GOTO 500
  420   PRINT "   MAY   ";: GOTO 500
  430   PRINT "   JUNE  ";: GOTO 500
  440   PRINT "   JULY  ";: GOTO 500
  450   PRINT "  AUGUST ";: GOTO 500
  460   PRINT "SEPTEMBER";: GOTO 500
  470   PRINT " OCTOBER ";: GOTO 500
  480   PRINT " NOVEMBER";: GOTO 500
  490   PRINT " DECEMBER";
  500   PRINT "******************";
  510   IF Z1=0 THEN  PRINT 365-S;"**" ELSE  PRINT 366-S;"**"
  520   PRINT TAB(27);Z
  530   PRINT "     Sun     Mon     Tue     Wed";
  540   PRINT "     Thr     Fri     Sat"
  550   PRINT X$;
  560   LET W=1
  570   PRINT : PRINT TAB(4);
  580   LET G=1
  590   LET D=D+1: LET D2=D-S
  600   IF D2>M(N) THEN 670
  610   IF D2>0 THEN  PRINT D2;
  620   PRINT TAB(4+8*G);
  630   LET G=G+1: IF G<8 THEN 590
  640   IF D2=M(N) THEN 680
  650   LET W=W+1: IF W<7 THEN 570
  660   PRINT
  670   LET D=D-G
  680 NEXT N
  690 PRINT J$;J$;J$;J$;J$;J$
  700 END