10 REM ...ACEY.ECB ..from ??? via EAGAN      Revised 3-14-81 REH
   20 DIM C(10),R(3)
   30 REM ...C(10) = Capital for 10 players
   40 REM ...R(1)  = 1st card
   50 REM ...R(2)  = 2nd card
   60 REM ...R(3)  = middle card
   70 PRINT "&K&J&J"
   80 PRINT TAB(21);"//^\\"
   90 PRINT TAB(19);"///   \\\"
  100 PRINT TAB(17);"///       \\\"
  110 PRINT TAB(15);"<<<  A C E Y  >>>"
  120 PRINT TAB(17);"\\\       ///"
  130 PRINT TAB(19);"\\\   ///"
  140 PRINT TAB(21);"\\V//"
  150 PRINT : PRINT 
  160 PRINT "How many players for ACEY-DUCEY ---=>";
  170 INPUT N
  180 IF N<2 THEN 1040
  190 IF N>10 THEN 1060
  200 FOR I=1 TO N
  210   LET C(I)=100
  220 NEXT I
  230 PRINT : PRINT "THANK YOU"
  240 PRINT 
  250 PRINT "Do you want the instructions, Y or N ---=>";
  260 INPUT (1,0)Q$: LET Q$=Q$+"N"
  270 PRINT 
  280 IF Q$(1,1)="Y" THEN 310
  290 IF Q$(1,1)="N" THEN 390
  300 GOTO 240
  310 PRINT "INSTRUCTIONS:": PRINT 
  320 PRINT "THIS IS THE ACEY DUCEY GAME"
  330 PRINT "THE POT IS INFINITE"
  340 PRINT "BET AS MUCH AS YOU HAVE"
  350 PRINT "YOU HAVE $100  ,THE MINIMUM BET IS $1"
  360 PRINT "AN ACE ON THE SECOND CARD IS HIGH"
  370 PRINT "GOOD LUCK........AND HAVE FUN "
  380 PRINT 
  390 PRINT "How many hands would you like to play ---=>";
  400 INPUT H0
  410 IF H0>100 THEN 1640
  420 GOTO 430
  430 LET H=1
  440 LET H1=H0-H
  450 PRINT "------------------------------------------------"
  460 PRINT 
  470 PRINT "Hand";H,TAB(15);
  480 IF H1>1 THEN  PRINT H1;" hands to go."
  490 IF H1=1 THEN  PRINT H1;" hand to go."
  500 IF H1=0 THEN  PRINT "LAST HAND."
  510 PRINT 
  520 FOR I=1 TO N
  530   PRINT "Player";TAB(15);I
  540   IF C(I)=0 THEN 1480
  550   LET J=C(I)
  560   PRINT "Capital:";TAB(15);J
  570   FOR I1=1 TO J
  580     LET Y=RND(0)
  590   NEXT I1
  600   FOR N3=1 TO 3
  610     LET Y=INT(RND(0)*13)+1
  620     LET R(N3)=Y
  630   NEXT N3
  640   PRINT "Card one:     ";
  650   IF R(1)=11 THEN 1080
  660   IF R(1)=12 THEN 1100
  670   IF R(1)=13 THEN 1120
  680   IF R(1)=1 THEN 1140
  690   PRINT R(1);"          ";
  700   PRINT "   Card two:   ";
  710   IF R(2)=11 THEN 1160
  720   IF R(2)=12 THEN 1180
  730   IF R(2)=13 THEN 1200
  740   IF R(2)=1 THEN 1220
  750   PRINT R(2)
  760   PRINT " Please wager ---=>";
  770   INPUT W
  780   IF W<1 THEN 1600
  790   IF W>C(I) THEN 1620
  800   IF W=C(I) THEN 1770
  810   PRINT TAB(15);"<*> Middle card: ";
  820   IF R(3)=11 THEN 1240
  830   IF R(3)=12 THEN 1260
  840   IF R(3)=13 THEN 1280
  850   IF R(3)=1 THEN 1300
  860   PRINT R(3)
  870   IF R(1)>R(2) THEN 1320
  880   IF R(2)>R(1) THEN 1400
  890   IF R(1)=R(2) THEN 1340
  900   PRINT " Your CAPITAL is now ";%$C;C(I)
  910   PRINT 
  920   GOTO 930
  930   GOTO 940
  940 NEXT I
  950 LET H=H+1
  960 IF H<=H0 THEN 440
  970 GOTO 980
  980 PRINT "I HOPE YOU ENJOYED THIS GAME"
  990 PRINT "DO YOU WISH TO PLAY AGAIN, Y or N ---=>";
 1000 INPUT (1,0)S$
 1010 LET S$=S$+"Y"
 1020 IF S$(1,1)="Y" THEN 160
 1030 IF S$(1,1)="y" THEN 160 ELSE 1790
 1040 PRINT "A  FEW MORE PLAYERS WOULD MAKE IT MORE FUN"
 1050 GOTO 160
 1060 PRINT "10 OR UNDER ONLY PLEASE"
 1070 GOTO 160
 1080 PRINT "JACK       ";
 1090 GOTO 700
 1100 PRINT "QUEEN      ";
 1110 GOTO 700
 1120 PRINT "KING       ";
 1130 GOTO 700
 1140 PRINT "ACE ";
 1150 GOTO 1680
 1160 PRINT "Jack"
 1170 GOTO 760
 1180 PRINT "Queen"
 1190 GOTO 760
 1200 PRINT "King"
 1210 GOTO 760
 1220 PRINT "Ace"
 1230 GOTO 1750
 1240 PRINT "JACK  <*>"
 1250 GOTO 870
 1260 PRINT "QUEEN  <*>"
 1270 GOTO 870
 1280 PRINT "KING  <*>"
 1290 GOTO 870
 1300 PRINT "ACE  <*>"
 1310 GOTO 1340
 1320 IF R(3)>=R(1) THEN 1340
 1330 IF R(3)>R(2) THEN 1370
 1340 PRINT "SORRY you lost  ";
 1350 LET C(I)=C(I)-W
 1360 GOTO 900
 1370 PRINT "  GOOD you WON  ";
 1380 LET C(I)=C(I)+W
 1390 GOTO 900
 1400 IF R(3)<=R(1) THEN 1420
 1410 IF R(3)<R(2) THEN 1450
 1420 PRINT "  SORRY you lost  ";
 1430 LET C(I)=C(I)-W
 1440 GOTO 900
 1450 PRINT "  GOOD you WON  ";
 1460 LET C(I)=C(I)+W
 1470 GOTO 900
 1480 PRINT "YOUR CAPITAL IS $ 0"
 1490 PRINT "SO YOU CAN CONTINUE, IF IT IS"
 1500 PRINT "O.K. WITH ALL OTHER PLAYERS"
 1510 PRINT "I WILL GIVE YOU ANNOTHER $20"
 1520 PRINT "DO YOU WANT ANNOTHER $20"
 1530 PRINT " ( Y=yes  N=no ) ---=>";
 1540 INPUT (1,0)S$
 1550 LET S$=S$+"Y"
 1560 IF S$(1,1)="N" THEN 940
 1570 IF S$(1,1)="n" THEN 940
 1580 LET C(I)=20
 1590 GOTO 550
 1600 PRINT "YOU MUST WAGER AT LEAST $1"
 1610 GOTO 760
 1620 PRINT "YOU WAGERED MORE THAN YOU HAVE"
 1630 GOTO 760
 1640 PRINT "THATS TOO MANY HANDS TO PLAY"
 1650 GOTO 390
 1660 PRINT "LETS PLAY MORE HANDS THAN THAT"
 1670 GOTO 390
 1680 PRINT 
 1690 PRINT TAB(14);"ACE.....HIGH OR LOW ?  (enter H or L)";
 1700 INPUT (1,0)" ---=>",D$: LET D$=D$+"H"
 1710 IF D$(1,1)="L" THEN 700
 1720 IF D$(1,1)="l" THEN 700
 1730 LET R(1)=14
 1740 GOTO 700
 1750 LET R(2)=14
 1760 GOTO 760
 1770 GOTO 1780
 1780 GOTO 810
 1790 PRINT 
 1800 FOR I=1 TO N
 1810   PRINT TAB(9);"Player:";%3I;I;
 1820   PRINT TAB(25);"Capital: ";%$C9I;C(I)
 1830 NEXT I
 1840 PRINT 
 1850 PRINT "            ACEY DEUCEY game terminated"
 1860 END